【サンプルコード】選択した図形の色をAutoLISPで自由に変更する｜ByLayerへの変更も可能

AutoLISPでAutoCADの作業を楽にしたいけど、プログラミングが苦手でコード（プログラム）を作れずにお困りではないでしょうか。マイナーなプログラム言語なのでサンプルコードを検索しても見つからずにお困りの方も多いはず。

そもそもAutoLISPってなに？という方はこちらの記事をご覧ください。
>>AutoCADユーザー必見！【AutoLISPを覚えるべきメリット5選】デメリットも解説

当記事ではAutoLISPのサンプルコードとして、選択した図形の色を自由に変更できるコードをご紹介します。初心者向けの解説付きなので、どんな方でも参考にしやすい内容になっています。

AutoLISPを覚えて今よりもAutoCADを効率化したい方はぜひ最後までお読みください。

サンプルコードの動作解説

今回ご紹介するAutoLISPのサンプルコードは以下のとおりです。

(defun c:test2
   (
    /
    mode colorindex ss n ent
   )

  ;;;色を変更する図形で選択セットを作成
  (initget 1 "1 2 3 4")
  (setq mode (getkword "対象図形の番号を入力してください。1:円のみ、2:赤い図形のみ、3:赤い円のみ、4:任意選択⇒"))

  ;;;モード毎に指定の図形を選択
  (cond
    
    ;;;図面上に存在する、すべての円を選択
    ((= mode "1")
     (setq ss (ssget "X" (list (cons 0 "circle"))))
    )

    ;;;図面上に存在する、色が赤の図形をすべて選択
    ((= mode "2")
     (setq ss (ssget "X" (list (cons 62 1))))
    )

    ;;;図面上に存在する、色が赤の円をすべて選択
    ((= mode "3")
     (setq ss (ssget "X" (list (cons 0 "circle") (cons 62 1))))
    )

    ;;;ユーザーが任意の図形を選択
    ((= mode "4")
     (setq ss (ssget))
    )
  )

  ;;;変更後の色番号を入力。整数以外が入力されたら再入力を求める。
  (initget 1)
  (setq colorindex (getint "変更後の色番号(0～256)を入力してください。※ByLayerは256 ⇒"))

  ;;;対象図形の図形情報を書き換える
  (if ss
    (progn
      (setq n 0)
      (repeat (sslength ss)

	    ;;;図形情報を取得
	    (setq ent (entget (ssname ss n)))

	    ;;;色の情報を変更または追加
	    (if (assoc 62 ent)
	      (setq ent (subst (cons 62 colorindex) (assoc 62 ent) ent))
	      (setq ent (append ent (list (cons 62 colorindex))))
        )

	    ;;;図形情報の書き換え
        (entmod ent)
        (setq n (1+ n))
      )
    )
  )

  ;;;終了
  (print "終了しました。")
  (princ)
)

上記のコードが書かれたlspファイルをロードして、コマンドラインに「test2」と入力すると動作が始まります。

動作の流れは以下のようになっています。

はこさん。

1つずつ解説していきます。

①図形選択のモードをユーザーに指定させる

まず最初に、図形選択の各モードに対応した1~4の番号をユーザーに指定させます。コードで示すと以下の2行（8行目～9行目）でユーザーにモードを指定させています。

;;;色を変更する図形で選択セットを作成
(initget 1 "1 2 3 4")
(setq mode (getkword "対象図形の番号を入力してください。1:円のみ、2:赤い図形のみ、3:赤い円のみ、4:任意選択⇒"))

「getkword」とはユーザーにキーワードの入力を求めて、入力されたキーワードを返すAutoLISP関数のこと。入力させるキーワードは「initget」で設定できます。

各モードの内容は次のとおり。モード毎の図形選択方法については後述します。

ちなみに「initget」の先頭に数値の1を記述すると、Enterの入力を禁止にできます。Enterが入力された場合は再度キーワードの入力を求めてくるので、「getkword」の返り値は必ず「initget」で設定したキーワードのいずれかになります。

はこさん。

入力するキーワードは数値ですが、返り値は文字列になるので注意してください。

「getkword」の返り値がローカル変数のmodeに格納され、次の動作へ移ります。

②指定されたモードに従って図形を選択

ローカル変数のmodeに格納された文字列から、図形選択のモードを判別して対象の図形を選択します。コードで示すと以下の部分（12行目～33行目）でモードの判別と図形の選択を行います。

;;;モード毎に指定の図形を選択
(cond
    
  ;;;図面上に存在する、すべての円を選択
  ((= mode "1")
   (setq ss (ssget "X" (list (cons 0 "circle"))))
  )

  ;;;図面上に存在する、色が赤の図形をすべて選択
  ((= mode "2")
   (setq ss (ssget "X" (list (cons 62 1))))
  )

  ;;;図面上に存在する、色が赤の円をすべて選択
  ((= mode "3")
   (setq ss (ssget "X" (list (cons 0 "circle") (cons 62 1))))
  )

  ;;;ユーザーが任意の図形を選択
  ((= mode "4")
   (setq ss (ssget))
  )
)

「cond」は複数の条件で処理の分岐ができるAutoLISP関数です。ローカル変数modeの中身を条件として、処理を分岐させています。

分岐後は「ssget」で図形を選択し、取得した選択セットをローカル変数ssに格納します。「ssget」とは選択した図形から選択セットを作成する関数のこと。選択範囲や図形の種類などさまざまな条件をつけて図形を選択できます。

たとえば、図面上に以下の図形が配置されている場合、モード番号が2の時は矢印で示した図形のみ選択されます。（赤い図形のみ選択）

ちなみに選択セットとは選択した図形を1つのグループにまとめたものです。専用の関数を使うことで選択セットから図形単体を指定できます。

「ssget」で取得した選択セットがローカル変数のssに格納されて次の動作へ移ります。

はこさん。

「ssget」は非常に便利でよく使う関数なので、使い方をしっかり覚えておきましょう。

③変更後の色番号をユーザーに入力させる

選択した図形の色を変えるため、変更後の色番号をユーザーに入力させます。コードで示すと以下の部分（36行目～37行目）で色番号の入力を行います。

;;;変更後の色番号を入力。整数以外が入力されたら再入力を求める。
(initget 1)
(setq colorindex (getint "変更後の色番号(0～256)を入力してください。※ByLayerは256 ⇒"))

「getint」はユーザーに整数の入力を求めるAutoLISPの関数です。モード番号を入力するときと同様に「initget」で1を与えているため、Enterが入力されたら再入力を求めます。

色番号と色の対応は「COLOR」コマンドで表示される下記の画面で確認できます。色にカーソルを合わせると色番号（インデックスカラー）が赤枠内に表示されます。

ユーザーが入力した整数はローカル変数のcolorindexに格納され、次の動作へ移ります。

はこさん。

257以上の整数を入力してもエラーで動作は止まりませんですが、色は変化しません。

④選択した図形の色番号をユーザーが入力した色番号に変更する

②で選択した全図形の色番号を、③でユーザーが入力した色番号に変更します。コードで示すと以下の部分（40行目～59行目）で色番号の変更を行います。

;;;対象図形の図形情報を書き換える
(if ss
  (progn
    (setq n 0)
    (repeat (sslength ss)

	  ;;;図形情報を取得
	  (setq ent (entget (ssname ss n)))

	  ;;;色の情報を変更または追加
	  (if (assoc 62 ent)
	    (setq ent (subst (cons 62 colorindex) (assoc 62 ent) ent))
	    (setq ent (append ent (list (cons 62 colorindex))))
      )

	  ;;;図形情報の書き換え
      (entmod ent)
      (setq n (1+ n))
    )
  )
)

「sslength」は選択セット内の図形数を返すAutoLISPの関数なので、選択された図形の数だけ「repeat」で動作を繰り返します。

図形が選択されていない（選択セット内の図形数が0）場合、ローカル変数ssの中身はnilのままです。「sslength」は引数がnilだとエラーで動作が止まるため、「repeat」の動作が始まる前に「if」でssの中身を判定しています。

はこさん。

図形が選択されていないときは何もせず終了します。

repeat内の動作解説

「repeat」内の動作では、最初に図形情報を取得してローカル変数のentに格納します。色の情報を表すグループコードは62なので、62から始まる連想リストを「assoc」で検索しています。

「assoc」で連想リストが見つかった場合は色番号を変更し、新しい図形情報をローカル変数のentに格納します。

;;;色の情報を変更または追加
(if (assoc 62 ent)
  (setq ent (subst (cons 62 colorindex) (assoc 62 ent) ent))
  (setq ent (append ent (list (cons 62 colorindex))))
)

色がByLayerのときは62から始まる連想リストが省略されているため、「assoc」の返り値はnilになります。この場合は図形情報に62から始まる連想リストを「append」で追加して、新しい図形情報を作成します。

「entmod」で新しい図形情報（ローカル変数のent）に書き換えることで、図形の色はユーザーが指定した色に変更されます。

たとえば、モード番号が2でユーザーが入力した色番号が110の場合は、赤い四角形だけ色が変わって緑になります。

はこさん。

図形情報の書き換えはさまざまな場面で応用できるので覚えておくと便利です。

サンプルコードを活かしてAutoCADをもっと効率化しよう

今回ご紹介したサンプルコードの動作内容を以下にまとめます。

選択図形の条件を変えたり、変更する図形情報を追加したりすることで、やりたい作業に特化したツールを作成できます。今回のサンプルコードを活かして、AutoCADの作業が楽になるツール作成に役立ててください。