ダイアログでユーザーの入力を楽にしよう！DCLを覚えるメリット3選｜表示方法も解説

test_dcl1:dialog
{
  label = "編集ボックス";

  :edit_box
  {
    label = "ラベル1";
    key = "edit1";
    width = 20;
  }
　:edit_box
  {
    label = "ラベル2";
    key = "edit2";
    width = 20;
  }
  ok_cancel;
}

test1:dialog
{
  key = "title";
  label = "";
  :column
  {
    fixed_width = true;
    :row
    {
      :text
      {
      	label = "挿入するブロック";
      	key = "text1";
      	width = 10;
      	fixed_width = true;
      }
      :popup_list
      {
      	key = "block_sel";
      	width = 15;
      	fixed_width = true;
      }
    }
    :list_box
    {
      label = "挿入する画層を選択";
      key = "layer_sel";
      multiple_select = false;
      width = 42;
      fixed_width = true;
    }
  }
  ok_cancel;
}

(defun c:test1
       (
	      /
	      blkname blkdata blklst layname laydata laylst set_block
	      sellayer dcl_id c_layer c_layer1 chkdia pt1
	     )

  ;;;ブロック名のリストを作成する
  (setq blkdata (tblnext "BLOCK" T))
  (while blkdata
    (setq blkname (cdr (assoc 2 blkdata)))
    (setq blklst (append blklst (list blkname)))
    (setq blkdata (tblnext "BLOCK"))
  )

  ;;;画層名のリストを作成する
  (setq laydata (tblnext "LAYER" T))
  (while laydata
    (setq layname (cdr (assoc 2 laydata)))
    (setq laylst (append laylst (list layname)))
    (setq laydata (tblnext "LAYER"))
  )
  
  ;;;ダイアログで選択した値を取得する
  (defun SaveTileVal()
    (setq sel_block (nth (atoi (get_tile "block_sel")) blklst))
    (setq sel_layer (nth (atoi (get_tile "layer_sel")) laylst))
  )
  
　;;;ダイアログを表示する準備
  (setq dcl_id (load_dialog "test1.dcl"))
  (new_dialog "test1" dcl_id)

  ;;;現在層を取得してタイトルに表示する
  (setq c_layer (getvar "clayer"))
  (setq c_layer1 (strcat "現在の画層は<" c_layer ">です。"))
  (set_tile "title" c_layer1)

　;;;ポップアップリストにブロック名のリストを流し込む
  (start_list "block_sel" 3)
  (mapcar 'add_list blklst)
  (end_list)

  ;;;リストボックスに画層名のリストを流し込む
  (start_list "layer_sel" 3)
  (mapcar 'add_list laylst)
  (end_list)

  ;;;OK,キャンセルボタンを押したときの動作
  (action_tile "accept" "(SaveTileVal)(done_dialog 1)")
  (action_tile "cancel" "(done_dialog 0)")

  ;;;ダイアログを終了する準備
  (setq chkdia (start_dialog))
  (unload_dialog dcl_id)

  ;;;OKボタンが押された場合はブロックを挿入する
  (if (= chkdia 1)
    (if sel_block
      (progn
　　　　 (setvar "clayer" sel_layer)
        (setq pt1 (getpoint "\n挿入位置を指定してください。"))
        (command "-insert" sel_block pt1 "" "" "")
        (setvar "clayer" c_layer)
      )
    )
  )
)